WoofWare.Myriad/WoofWare.Myriad.Plugins/JsonParseGenerator.fs

namespace WoofWare.Myriad.Plugins

open System
open System.Text
open Fantomas.FCS.Syntax
open Fantomas.FCS.SyntaxTrivia

type internal JsonParseOutputSpec =
    {
        ExtensionMethods : bool
    }

[<RequireQualifiedAccess>]
module internal JsonParseGenerator =
    open Fantomas.FCS.Text.Range

    type JsonParseOption =
        {
            JsonNumberHandlingArg : SynExpr option
        }

        static member None =
            {
                JsonNumberHandlingArg = None
            }

    /// (match {indexed} with | null -> raise (System.Collections.Generic.KeyNotFoundException ()) | v -> v)
    let assertNotNull (propertyName : SynExpr) (indexed : SynExpr) =
        let raiseExpr =
            SynExpr.applyFunction
                (SynExpr.createIdent "sprintf")
                (SynExpr.CreateConst "Required key '%s' not found on JSON object")
            |> SynExpr.applyTo (SynExpr.paren propertyName)
            |> SynExpr.paren
            |> SynExpr.applyFunction (
                SynExpr.createLongIdent [ "System" ; "Collections" ; "Generic" ; "KeyNotFoundException" ]
            )
            |> SynExpr.paren
            |> SynExpr.applyFunction (SynExpr.createIdent "raise")

        [
            SynMatchClause.create SynPat.createNull raiseExpr
            SynMatchClause.create (SynPat.named "v") (SynExpr.createIdent "v")
        ]
        |> SynExpr.createMatch indexed
        |> SynExpr.paren

    /// {node}.AsValue().GetValue<{typeName}> ()
    /// If `propertyName` is Some, uses `assertNotNull {node}` instead of `{node}`.
    let asValueGetValue (propertyName : SynExpr option) (typeName : string) (node : SynExpr) : SynExpr =
        match propertyName with
        | None -> node
        | Some propertyName -> assertNotNull propertyName node
        |> SynExpr.callMethod "AsValue"
        |> SynExpr.callGenericMethod' "GetValue" typeName

    let asValueGetValueIdent (propertyName : SynExpr option) (typeName : LongIdent) (node : SynExpr) : SynExpr =
        match propertyName with
        | None -> node
        | Some propertyName -> assertNotNull propertyName node
        |> SynExpr.callMethod "AsValue"
        |> SynExpr.callGenericMethod "GetValue" typeName

    /// {node}.AsObject()
    /// If `propertyName` is Some, uses `assertNotNull {node}` instead of `{node}`.
    let asObject (propertyName : SynExpr option) (node : SynExpr) : SynExpr =
        match propertyName with
        | None -> node
        | Some propertyName -> assertNotNull propertyName node
        |> SynExpr.callMethod "AsObject"

    /// {type}.jsonParse {node}
    let typeJsonParse (typeName : LongIdent) (node : SynExpr) : SynExpr =
        node
        |> SynExpr.applyFunction (SynExpr.createLongIdent' (typeName @ [ Ident.create "jsonParse" ]))

    /// collectionType is e.g. "List"; we'll be calling `ofSeq` on it.
    /// body is the body of a lambda which takes a parameter `elt`.
    /// {assertNotNull node}.AsArray()
    /// |> Seq.map (fun elt -> {body})
    /// |> {collectionType}.ofSeq
    let asArrayMapped
        (propertyName : SynExpr option)
        (collectionType : string)
        (node : SynExpr)
        (body : SynExpr)
        : SynExpr
        =
        match propertyName with
        | None -> node
        | Some propertyName -> assertNotNull propertyName node
        |> SynExpr.callMethod "AsArray"
        |> SynExpr.pipeThroughFunction (
            SynExpr.applyFunction (SynExpr.createLongIdent [ "Seq" ; "map" ]) (SynExpr.createLambda "elt" body)
        )
        |> SynExpr.pipeThroughFunction (SynExpr.createLongIdent [ collectionType ; "ofSeq" ])

    /// match {node} with | null -> None | v -> {body} |> Some
    /// Use the variable `v` to get access to the `Some`.
    let createParseLineOption (node : SynExpr) (body : SynExpr) : SynExpr =
        let body = SynExpr.pipeThroughFunction (SynExpr.createIdent "Some") body

        [
            SynMatchClause.create SynPat.createNull (SynExpr.createIdent "None")
            SynMatchClause.create (SynPat.named "v") body
        ]
        |> SynExpr.createMatch node

    /// Given e.g. "float", returns "System.Double.Parse"
    let parseFunction (typeName : string) : LongIdent =
        let qualified =
            match Primitives.qualifyType typeName with
            | Some x -> x
            | None -> failwith $"Could not recognise type %s{typeName} as a primitive."

        List.append qualified [ Ident.create "Parse" ]

    /// fun kvp -> let key = {key(kvp)} in let value = {value(kvp)} in (key, value))
    /// The inputs will be fed with appropriate SynExprs to apply them to the `kvp.Key` and `kvp.Value` args.
    let dictionaryMapper (key : SynExpr -> SynExpr) (value : SynExpr -> SynExpr) : SynExpr =
        let keyArg = SynExpr.createLongIdent [ "kvp" ; "Key" ] |> SynExpr.paren

        let valueArg = SynExpr.createLongIdent [ "kvp" ; "Value" ] |> SynExpr.paren

        // No need to paren here, we're on the LHS of a `let`
        SynExpr.tupleNoParen [ SynExpr.createIdent "key" ; SynExpr.createIdent "value" ]
        |> SynExpr.createLet [ SynBinding.basic [ Ident.create "value" ] [] (value valueArg) ]
        |> SynExpr.createLet [ SynBinding.basic [ Ident.create "key" ] [] (key keyArg) ]
        |> SynExpr.createLambda "kvp"

    /// A conforming JSON object has only strings as keys. But it would be reasonable to allow the user
    /// to parse these as URIs, for example.
    let parseKeyString (desiredType : SynType) (key : SynExpr) : SynExpr =
        match desiredType with
        | String -> key
        | Uri ->
            key
            |> SynExpr.pipeThroughFunction (SynExpr.createLongIdent [ "System" ; "Uri" ])
        | _ ->
            failwithf
                $"Unable to parse the key type %+A{desiredType} of a JSON object. Keys are strings, and this plugin does not know how to convert to that from a string."

    /// Given `node.["town"]`, for example, choose how to obtain a JSON value from it.
    /// The property name is used in error messages at runtime to show where a JSON
    /// parse error occurred; supply `None` to indicate "don't validate".
    let rec parseNode
        (propertyName : SynExpr option)
        (options : JsonParseOption)
        (fieldType : SynType)
        (node : SynExpr)
        : SynExpr
        =
        // TODO: parsing format for DateTime etc
        match fieldType with
        | DateOnly ->
            node
            |> asValueGetValue propertyName "string"
            |> SynExpr.pipeThroughFunction (SynExpr.createLongIdent [ "System" ; "DateOnly" ; "Parse" ])
        | Uri ->
            node
            |> asValueGetValue propertyName "string"
            |> SynExpr.pipeThroughFunction (SynExpr.createLongIdent [ "System" ; "Uri" ])
        | Guid ->
            node
            |> asValueGetValue propertyName "string"
            |> SynExpr.pipeThroughFunction (SynExpr.createLongIdent [ "System" ; "Guid" ; "Parse" ])
        | DateTime ->
            node
            |> asValueGetValue propertyName "string"
            |> SynExpr.pipeThroughFunction (SynExpr.createLongIdent [ "System" ; "DateTime" ; "Parse" ])
        | NumberType typeName ->
            let basic = asValueGetValue propertyName typeName node

            match options.JsonNumberHandlingArg with
            | None -> basic
            | Some option ->
                let cond =
                    SynExpr.DotGet (SynExpr.createIdent "exc", range0, SynLongIdent.createS "Message", range0)
                    |> SynExpr.callMethodArg "Contains" (SynExpr.CreateConst "cannot be converted to")

                let handler =
                    asValueGetValue propertyName "string" node
                    |> SynExpr.pipeThroughFunction (SynExpr.createLongIdent' (parseFunction typeName))
                    |> SynExpr.ifThenElse
                        (SynExpr.equals
                            option
                            (SynExpr.createLongIdent
                                [
                                    "System"
                                    "Text"
                                    "Json"
                                    "Serialization"
                                    "JsonNumberHandling"
                                    "AllowReadingFromString"
                                ]))
                        SynExpr.reraise
                    |> SynExpr.ifThenElse cond SynExpr.reraise

                basic
                |> SynExpr.pipeThroughTryWith
                    (SynPat.IsInst (
                        SynType.LongIdent (SynLongIdent.createS' [ "System" ; "InvalidOperationException" ]),
                        range0
                    ))
                    handler
        | PrimitiveType typeName -> asValueGetValueIdent propertyName typeName node
        | OptionType ty ->
            parseNode None options ty (SynExpr.createIdent "v")
            |> createParseLineOption node
        | ListType ty ->
            parseNode None options ty (SynExpr.createIdent "elt")
            |> asArrayMapped propertyName "List" node
        | ArrayType ty ->
            parseNode None options ty (SynExpr.createIdent "elt")
            |> asArrayMapped propertyName "Array" node
        | IDictionaryType (keyType, valueType) ->
            node
            |> asObject propertyName
            |> SynExpr.pipeThroughFunction (
                SynExpr.applyFunction
                    (SynExpr.createLongIdent [ "Seq" ; "map" ])
                    (dictionaryMapper (parseKeyString keyType) (parseNode None options valueType))
            )
            |> SynExpr.pipeThroughFunction (SynExpr.createIdent "dict")
        | DictionaryType (keyType, valueType) ->
            node
            |> asObject propertyName
            |> SynExpr.pipeThroughFunction (
                SynExpr.applyFunction
                    (SynExpr.createLongIdent [ "Seq" ; "map" ])
                    (dictionaryMapper (parseKeyString keyType) (parseNode None options valueType))
            )
            |> SynExpr.pipeThroughFunction (
                SynExpr.applyFunction
                    (SynExpr.createLongIdent [ "Seq" ; "map" ])
                    (SynExpr.createLongIdent [ "System" ; "Collections" ; "Generic" ; "KeyValuePair" ])
            )
            |> SynExpr.pipeThroughFunction (
                SynExpr.createLongIdent [ "System" ; "Collections" ; "Generic" ; "Dictionary" ]
            )
        | IReadOnlyDictionaryType (keyType, valueType) ->
            node
            |> asObject propertyName
            |> SynExpr.pipeThroughFunction (
                SynExpr.applyFunction
                    (SynExpr.createLongIdent [ "Seq" ; "map" ])
                    (dictionaryMapper (parseKeyString keyType) (parseNode None options valueType))
            )
            |> SynExpr.pipeThroughFunction (SynExpr.createIdent "readOnlyDict")
        | MapType (keyType, valueType) ->
            node
            |> asObject propertyName
            |> SynExpr.pipeThroughFunction (
                SynExpr.applyFunction
                    (SynExpr.createLongIdent [ "Seq" ; "map" ])
                    (dictionaryMapper (parseKeyString keyType) (parseNode None options valueType))
            )
            |> SynExpr.pipeThroughFunction (SynExpr.createLongIdent [ "Map" ; "ofSeq" ])
        | BigInt ->
            node
            |> SynExpr.callMethod "ToJsonString"
            |> SynExpr.paren
            |> SynExpr.applyFunction (SynExpr.createLongIdent [ "System" ; "Numerics" ; "BigInteger" ; "Parse" ])
        | _ ->
            // Let's just hope that we've also got our own type annotation!
            let typeName =
                match fieldType with
                | SynType.LongIdent ident -> ident.LongIdent
                | _ -> failwith $"Unrecognised type: %+A{fieldType}"

            match propertyName with
            | None -> node
            | Some propertyName -> assertNotNull propertyName node
            |> typeJsonParse typeName

    /// propertyName is probably a string literal, but it could be a [<Literal>] variable
    /// The result of this function is the body of a let-binding (not including the LHS of that let-binding).
    let createParseRhs (options : JsonParseOption) (propertyName : SynExpr) (fieldType : SynType) : SynExpr =
        let objectToParse = SynExpr.createIdent "node" |> SynExpr.index propertyName
        parseNode (Some propertyName) options fieldType objectToParse

    let isJsonNumberHandling (literal : LongIdent) : bool =
        match List.rev literal |> List.map (fun ident -> ident.idText) with
        | [ _ ; "JsonNumberHandling" ]
        | [ _ ; "JsonNumberHandling" ; "Serialization" ]
        | [ _ ; "JsonNumberHandling" ; "Serialization" ; "Json" ]
        | [ _ ; "JsonNumberHandling" ; "Serialization" ; "Json" ; "Text" ]
        | [ _ ; "JsonNumberHandling" ; "Serialization" ; "Json" ; "Text" ; "System" ] -> true
        | _ -> false

    /// `populateNode` will be inserted before we return the `node` variable.
    ///
    /// That is, we give you access to a `JsonNode` called `node`,
    /// and you must return a `typeName`.
    let scaffolding (spec : JsonParseOutputSpec) (typeName : LongIdent) (functionBody : SynExpr) : SynModuleDecl =
        let xmlDoc = PreXmlDoc.create "Parse from a JSON node."

        let returnInfo = SynType.createLongIdent typeName

        let inputArg = "node"
        let functionName = Ident.create "jsonParse"

        let arg =
            SynPat.named inputArg
            |> SynPat.annotateType (SynType.createLongIdent' [ "System" ; "Text" ; "Json" ; "Nodes" ; "JsonNode" ])

        if spec.ExtensionMethods then
            let binding =
                SynBinding.basic [ functionName ] [ arg ] functionBody
                |> SynBinding.withXmlDoc xmlDoc
                |> SynBinding.withReturnAnnotation returnInfo
                |> SynMemberDefn.staticMember

            let componentInfo =
                SynComponentInfo.createLong typeName
                |> SynComponentInfo.withDocString (PreXmlDoc.create "Extension methods for JSON parsing")

            let containingType =
                SynTypeDefnRepr.augmentation ()
                |> SynTypeDefn.create componentInfo
                |> SynTypeDefn.withMemberDefns [ binding ]

            SynModuleDecl.Types ([ containingType ], range0)
        else
            SynBinding.basic [ functionName ] [ arg ] functionBody
            |> SynBinding.withXmlDoc xmlDoc
            |> SynBinding.withReturnAnnotation returnInfo
            |> SynModuleDecl.createLet

    let getParseOptions (fieldAttrs : SynAttribute list) =
        (JsonParseOption.None, fieldAttrs)
        ||> List.fold (fun options attr ->
            if
                (SynLongIdent.toString attr.TypeName)
                    .EndsWith ("JsonNumberHandling", StringComparison.Ordinal)
            then
                let qualifiedEnumValue =
                    match SynExpr.stripOptionalParen attr.ArgExpr with
                    | SynExpr.LongIdent (_, SynLongIdent (ident, _, _), _, _) when isJsonNumberHandling ident ->
                        // Make sure it's fully qualified
                        SynExpr.createLongIdent
                            [
                                "System"
                                "Text"
                                "Json"
                                "Serialization"
                                "JsonNumberHandling"
                                "AllowReadingFromString"
                            ]
                    | _ -> attr.ArgExpr

                {
                    JsonNumberHandlingArg = Some qualifiedEnumValue
                }
            else
                options
        )

    let createRecordMaker (spec : JsonParseOutputSpec) (fields : SynFieldData<Ident> list) =
        let assignments =
            fields
            |> List.mapi (fun i fieldData ->
                let propertyNameAttr =
                    fieldData.Attrs
                    |> List.tryFind (fun attr ->
                        (SynLongIdent.toString attr.TypeName)
                            .EndsWith ("JsonPropertyName", StringComparison.Ordinal)
                    )

                let options = getParseOptions fieldData.Attrs

                let propertyName =
                    match propertyNameAttr with
                    | None ->
                        let sb = StringBuilder fieldData.Ident.idText.Length

                        sb.Append (Char.ToLowerInvariant fieldData.Ident.idText.[0])
                        |> ignore<StringBuilder>

                        if fieldData.Ident.idText.Length > 1 then
                            sb.Append (fieldData.Ident.idText.Substring 1) |> ignore<StringBuilder>

                        sb.ToString () |> SynExpr.CreateConst
                    | Some name -> name.ArgExpr

                createParseRhs options propertyName fieldData.Type
                |> SynBinding.basic [ Ident.create $"arg_%i{i}" ] []
            )

        let finalConstruction =
            fields
            |> List.mapi (fun i fieldData ->
                (SynLongIdent.createI fieldData.Ident, true), Some (SynExpr.createIdent $"arg_%i{i}")
            )
            |> AstHelper.instantiateRecord

        (finalConstruction, assignments)
        ||> List.fold (fun final assignment -> SynExpr.createLet [ assignment ] final)

    let createUnionMaker (spec : JsonParseOutputSpec) (typeName : LongIdent) (fields : UnionCase<Ident> list) =
        fields
        |> List.map (fun case ->
            let propertyName = JsonSerializeGenerator.getPropertyName case.Ident case.Attrs

            let body =
                if case.Fields.IsEmpty then
                    SynExpr.createLongIdent' (typeName @ [ case.Ident ])
                else
                    case.Fields
                    |> List.map (fun field ->
                        let propertyName = JsonSerializeGenerator.getPropertyName field.Ident field.Attrs
                        let options = getParseOptions field.Attrs
                        createParseRhs options propertyName field.Type
                    )
                    |> SynExpr.tuple
                    |> SynExpr.applyFunction (SynExpr.createLongIdent' (typeName @ [ case.Ident ]))
                    |> SynExpr.createLet
                        [
                            SynExpr.index (SynExpr.CreateConst "data") (SynExpr.createIdent "node")
                            |> assertNotNull (SynExpr.CreateConst "data")
                            |> SynBinding.basic [ Ident.create "node" ] []
                        ]

            match propertyName with
            | SynExpr.Const (synConst, _) ->
                SynMatchClause.SynMatchClause (
                    SynPat.createConst synConst,
                    None,
                    body,
                    range0,
                    DebugPointAtTarget.Yes,
                    {
                        ArrowRange = Some range0
                        BarRange = Some range0
                    }
                )
            | _ ->
                SynMatchClause.create (SynPat.named "x") body
                |> SynMatchClause.withWhere (SynExpr.equals (SynExpr.createIdent "x") propertyName)
        )
        |> fun l ->
            l
            @ [
                let fail =
                    SynExpr.plus (SynExpr.CreateConst "Unrecognised 'type' field value: ") (SynExpr.createIdent "v")
                    |> SynExpr.paren
                    |> SynExpr.applyFunction (SynExpr.createIdent "failwith")

                SynMatchClause.SynMatchClause (
                    SynPat.named "v",
                    None,
                    fail,
                    range0,
                    DebugPointAtTarget.Yes,
                    {
                        ArrowRange = Some range0
                        BarRange = Some range0
                    }
                )
            ]
        |> SynExpr.createMatch (SynExpr.createIdent "ty")
        |> SynExpr.createLet
            [
                let property = SynExpr.CreateConst "type"

                SynExpr.createIdent "node"
                |> SynExpr.index property
                |> assertNotNull property
                |> SynExpr.pipeThroughFunction (
                    SynExpr.createLambda
                        "v"
                        (SynExpr.callGenericMethod "GetValue" [ Ident.create "string" ] (SynExpr.createIdent "v"))
                )
                |> SynBinding.basic [ Ident.create "ty" ] []
            ]

    let createModule (namespaceId : LongIdent) (spec : JsonParseOutputSpec) (typeDefn : SynTypeDefn) =
        let (SynTypeDefn (synComponentInfo, synTypeDefnRepr, _members, _implicitCtor, _, _)) =
            typeDefn

        let (SynComponentInfo (_attributes, _typeParams, _constraints, ident, _, _preferPostfix, access, _)) =
            synComponentInfo

        let attributes =
            if spec.ExtensionMethods then
                [ SynAttribute.autoOpen ]
            else
                [ SynAttribute.requireQualifiedAccess ; SynAttribute.compilationRepresentation ]

        let xmlDoc =
            let fullyQualified = ident |> Seq.map (fun i -> i.idText) |> String.concat "."

            let description =
                if spec.ExtensionMethods then
                    "extension members"
                else
                    "methods"

            $"Module containing JSON parsing %s{description} for the %s{fullyQualified} type"
            |> PreXmlDoc.create

        let moduleName =
            if spec.ExtensionMethods then
                match ident with
                | [] -> failwith "unexpectedly got an empty identifier for record name"
                | ident ->
                    let expanded =
                        List.last ident
                        |> fun i -> i.idText
                        |> fun s -> s + "JsonParseExtension"
                        |> Ident.create

                    List.take (List.length ident - 1) ident @ [ expanded ]
            else
                ident

        let info =
            SynComponentInfo.createLong moduleName
            |> SynComponentInfo.withDocString xmlDoc
            |> SynComponentInfo.setAccessibility access
            |> SynComponentInfo.addAttributes attributes

        let decl =
            match synTypeDefnRepr with
            | SynTypeDefnRepr.Simple (SynTypeDefnSimpleRepr.Record (_accessibility, fields, _range), _) ->
                fields |> List.map SynField.extractWithIdent |> createRecordMaker spec
            | SynTypeDefnRepr.Simple (SynTypeDefnSimpleRepr.Union (_accessibility, cases, _range), _) ->
                let optionGet (i : Ident option) =
                    match i with
                    | None -> failwith "WoofWare.Myriad requires union cases to have identifiers on each field."
                    | Some i -> i

                cases
                |> List.map SynUnionCase.extract
                |> List.map (UnionCase.mapIdentFields optionGet)
                |> createUnionMaker spec ident
            | _ -> failwithf "Not a record or union type"

        [ scaffolding spec ident decl ]
        |> SynModuleDecl.nestedModule info
        |> List.singleton
        |> SynModuleOrNamespace.createNamespace namespaceId

open Myriad.Core

/// Myriad generator that provides a method (possibly an extension method) for a record type,
/// containing a JSON parse function.
[<MyriadGenerator("json-parse")>]
type JsonParseGenerator () =

    interface IMyriadGenerator with
        member _.ValidInputExtensions = [ ".fs" ]

        member _.Generate (context : GeneratorContext) =
            let ast, _ =
                Ast.fromFilename context.InputFilename |> Async.RunSynchronously |> Array.head

            let recordsAndUnions =
                Ast.extractTypeDefn ast
                |> List.map (fun (name, defns) ->
                    defns
                    |> List.choose (fun defn ->
                        if Ast.isRecord defn then Some defn
                        elif Ast.isDu defn then Some defn
                        else None
                    )
                    |> fun defns -> name, defns
                )

            let namespaceAndTypes =
                recordsAndUnions
                |> List.choose (fun (ns, types) ->
                    types
                    |> List.choose (fun typeDef ->
                        match Ast.getAttribute<JsonParseAttribute> typeDef with
                        | None -> None
                        | Some attr ->
                            let arg =
                                match SynExpr.stripOptionalParen attr.ArgExpr with
                                | SynExpr.Const (SynConst.Bool value, _) -> value
                                | SynExpr.Const (SynConst.Unit, _) -> JsonParseAttribute.DefaultIsExtensionMethod
                                | arg ->
                                    failwith
                                        $"Unrecognised argument %+A{arg} to [<%s{nameof JsonParseAttribute}>]. Literals are not supported. Use `true` or `false` (or unit) only."

                            let spec =
                                {
                                    ExtensionMethods = arg
                                }

                            Some (typeDef, spec)
                    )
                    |> function
                        | [] -> None
                        | ty -> Some (ns, ty)
                )

            let modules =
                namespaceAndTypes
                |> List.collect (fun (ns, types) ->
                    types |> List.map (fun (ty, spec) -> JsonParseGenerator.createModule ns spec ty)
                )

            Output.Ast modules