Reduce duplication (#149)

WoofWare.Myriad.Plugins/SynExpr/SynField.fs

@@ -0,0 +1,39 @@
+namespace WoofWare.Myriad.Plugins
+
+open Fantomas.FCS.Syntax
+
+type internal SynFieldData<'Ident> =
+    {
+        Attrs : SynAttribute list
+        Ident : 'Ident
+        Type : SynType
+    }
+
+[<RequireQualifiedAccess>]
+module internal SynField =
+    /// Get the useful information out of a SynField.
+    let extract (SynField (attrs, _, id, fieldType, _, _, _, _, _)) : SynFieldData<Ident option> =
+        {
+            Attrs = attrs |> List.collect (fun l -> l.Attributes)
+            Ident = id
+            Type = fieldType
+        }
+
+    let mapIdent<'a, 'b> (f : 'a -> 'b) (x : SynFieldData<'a>) : SynFieldData<'b> =
+        let ident = f x.Ident
+
+        {
+            Attrs = x.Attrs
+            Ident = ident
+            Type = x.Type
+        }
+
+    /// Throws if the field has no identifier.
+    let extractWithIdent (f : SynField) : SynFieldData<Ident> =
+        f
+        |> extract
+        |> mapIdent (fun ident ->
+            match ident with
+            | None -> failwith "expected field identifier to have a value, but it did not"
+            | Some i -> i
+        )

WoofWare.Myriad.Plugins/SynExpr/SynUnionCase.fs

@@ -0,0 +1,32 @@
+namespace WoofWare.Myriad.Plugins
+
+open Fantomas.FCS.Syntax
+
+type internal UnionCase<'Ident> =
+    {
+        Fields : SynFieldData<'Ident> list
+        Attrs : SynAttribute list
+        Ident : Ident
+    }
+
+[<RequireQualifiedAccess>]
+module internal SynUnionCase =
+    let extract (SynUnionCase (attrs, id, caseType, _, _, _, _)) : UnionCase<Ident option> =
+        match caseType with
+        | SynUnionCaseKind.FullType _ -> failwith "WoofWare.Myriad does not support FullType union cases."
+        | SynUnionCaseKind.Fields fields ->
+
+        let fields = fields |> List.map SynField.extract
+
+        let id =
+            match id with
+            | SynIdent.SynIdent (ident, _) -> ident
+
+        // As far as I can tell, there's no way to get any attributes here? :shrug:
+        let attrs = attrs |> List.collect (fun l -> l.Attributes)
+
+        {
+            Fields = fields
+            Attrs = attrs
+            Ident = id
+        }